[SOLVED] silvaco capability in order to gain current and voltage characteristics

[bidarmard]

Hello everybody

Is it possible to gain the subthreshold current and iD and Vg in a NMOS with just the following parameters in silvaco .
L=2 (um) , W=10 (um) , electron mobility=500 (cm^2/v) , oxide thickness=50 (nm) , Na=10^15 (cm^-3) ??

I'll be grateful if you kindly answer my question.

 

[Colbhaidh]

Yes. It would be quite easy. Just set the substrate doping to 10E15, put N doping either side of the 2um gate at around 1E20, set the gate to n.poly and override the mobility. The results will be per um width so multiply by 10.

 

[bidarmard]

hi colbhaidh
I found silvaco example code in it's toolbar as follow if it is possible please help me to modify this code to reach the desired parameters.


go athena
# Start Athena running...


grid.model template=MOS

# remember to assign width.str and depth.str

init orientation=100 c.boron=1e14 space.mul=3 width.str=0.5 depth.str=0.8

#method adapt
#adapt.par accur.mult = 1

#pwell formation including masking off of the nwell
#
diffus time=30 temp=1000 dryo2 press=1.00 hcl=3
#
etch oxide thick=0.02
#
#P-well Implant
#
implant boron dose=1e15 energy=100 pears

#
diffus temp=950 time=100 weto2 hcl=3
#
#P-well implant not shown -
#
# welldrive starts here
diffus time=50 temp=1000 t.rate=4.000 dryo2 press=0.10 hcl=3
#
diffus time=220 temp=1200 nitro press=1
#mobility mun=500
#
diffus time=90 temp=1200 t.rate=-4.444 nitro press=1
#
etch oxide all
#
#sacrificial "cleaning" oxide
diffus time=20 temp=1000 dryo2 press=1 hcl=3
#
etch oxide all
#
#gate oxide grown here:-
method grid.ox=0.0035
diffus time=11 temp=925 dryo2 press=1.00 hcl=3

# Extract a design parameter.....

extract name="gateox" thickness oxide mat.occno=1 x.val=0.49
#
#vt adjust implant
adapt.par accur.mult = 5
implant boron dose=1e15 energy=10 pearson

#
depo poly thick=0.2 divi=10
#
#from now on the situation is 2-D
#
etch poly left p1.x=0.35
#
method adapt
method fermi compress
method grid.ox=0.035
diffuse time=3 temp=900 weto2 press=1.0
adapt.par accur.mult=1
#
implant phosphor dose=3.0e13 energy=20 pearson
#
depo oxide thick=0.120 divisions=8
#
etch oxide dry thick=0.140
#
implant arsenic dose=5.0e15 energy=50 pearson

#
method fermi compress
diffuse time=1 temp=900 nitro press=1.0
#

#
deposit alumin thick=0.03 divi=2
etch alumin right p1.x=0.18


# Extract another design parameters...
# extract final S/D Xj...
extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1
# extract the long chan Vt...
extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49
# extract a curve of conductance versus bias....
extract start material="Polysilicon" mat.occno=1 bias=0.0 bias.step=0.2 bias.stop=2 x.val=0.45
extract done name="sheet cond v bias" curve(bias,1dn.conduct material="Silicon" mat.occno=1 region.occno=1) outfile="amex05.dat"
tonyplot amex05.dat
# extract the N++ regions sheet resistance...
extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1
# extract the sheet rho under the spacer, of the LDD region...
extract name="ldd sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.3 region.occno=1
# extract the surface conc under the channel....
extract name="chan surf conc" surf.conc impurity="Net Doping" material="Silicon" mat.occno=1 x.val=0.45

structure mirror right

electrode name=gate x=0.5 y=0.1
electrode name=source x=0.1
electrode name=drain x=0.9
electrode name=substrate backside

structure outfile=amex05.str

# plot the structure
tonyplot amex05.str -set amex05.set

 

[davidmarsh404]

In this work the forward J–V characteristics of 4H–SiC p–i–n diodes are ... to about 523K in the whole explored current range extending over nine orders of magnitude. ... electrically effective profile on the device current handling capabilities. ... has leaded these tools to gain a key role in the optimization of existing devices.


thanks for sharing.


**broken link removed**

 

[Colbhaidh]

That way to complex. Try the following. Note that this defaults to silvaco's mobility model and not the 500 you specified for mun. Are you shure you want to override Silvaco's complex mobility model with just a value of 500?

go athena

grid.model template=MOS

#P-substrate set to channel doping Na = 10E15
init orientation=100 c.boron=1e16 space.mul=3 width.str=2.0 depth.str=2.0

#gate oxide
deposit oxide thick=0.05
#gate poly
depo poly thick=0.2 divi=10
etch poly left p1.x=1.0
#N+SD implants
implant phosphor dose=3.0e13 energy=30 pearson
implant arsenic  dose=5.0e15 energy=65 pearson
#
#Anneal implants
diffuse time=10 temp=900 nitrogen

#etch oxide from contact regions
etch oxide thick=0.05
#
deposit alumin thick=0.03 divi=2
etch alumin right p1.x=0.6

structure mirror right

electrode name=gate x=1.5 y=-0.25
electrode name=source x=0.1
electrode name=drain x=3.9
electrode name=substrate backside

structure outfile=nmos2.str
structure infile=nmos2.str

go atlas

# set material models
models cvt srh print 

contact name=gate n.poly
interface qf=3e10

method newton
solve init

# Bias the drain 
solve vdrain=0.1 

# Ramp the gate
log outf=nmos2.log master
solve vgate=0.00 vstep=0.05 vfinal=1.0 name=gate
solve vgate=1.00 vstep=0.20 vfinal=5.0 name=gate
save outf=nmos2.str

quit

 

[bidarmard]

thank you colbhaidh for your attention,yes 500 as a mobility is a part of my asked project, another question is that how it is possible to gain the band energy diagram?

- - - Updated - - -

and another one is that how can we reach a mobility diagram in such a device?

 

[Colbhaidh]

To set mobility use the mobility statement (theres a surprise)
So change the Atlas code as follows:

go atlas

# set material models

mobility vsatn=500
contact name=gate n.poly
interface qf=3e10

method newton
solve init

# Bias the drain
solve vdrain=0.00 vstep=0.005 vfinal=0.1 name=drain

# Ramp the gate
log outf=nmos2.log master
solve vgate=0.00 vstep=0.05 vfinal=1.0 name=gate
save outf=nmos2VG0.str
solve vgate=1.00 vstep=0.20 vfinal=5.0 name=gate
save outf=nmos2VG5.str

quit

to see the energy band just use the electron and hole concentrations available in Tonyplot

- - - Updated - - -

Place the following before the method statement

output con.band val.band e.mobility

This will make the conduction and valence bands and mobility available for plotting in Tonyplot

 

[Colbhaidh]

Sorry the mobility line should be:

mobility MUN = 500.0

 

[bidarmard]

thank you everybody for your kindly help and attention.