Looking for info about PIN diode model

[filtershaoyong]

Most foundry don't provide PIN diode, I want some information about it. Can anyone help me about the model of PIN diode?
thank you!

 

[Borber]

ba592_in

Here are models of two PIN diodes from Infineon:
*
*
.SUBCKT BA592_IN 100 200
*Package SOD323:
L1 1 10 0.55nH
C2 10 2 110fF
L2 10 100 0.67nH
L3 2 200 0.55nH
*RF Resistances: R1,R2,and G1
R1 1 3 101.1054m
R2 3 4 1.7826k
R4 1 2 700e9
G1 3 4 POLY(2) 3 4 9 0 0 0 0 0 36.0461m
*Constant reverse-bias capacitance
C1 3 2 670.0f
*Junction diode
D1 4 2 DIO1
*Reverse-bias clamp
G2 0 5 4 2 1.0
D3 0 5 DIO3
V1 5 6 0.0
D4 6 0 DIO3
*Calculation of fractional power current
H1 7 0 V1 1.0
V2 7 8 0.0
D2 8 0 DIO2
*Fractional power current to voltage conversion
F1 0 9 v2 10.0
R3 9 0 1000.0
.MODEL DIO1 D(IS=3.8637f N=1.0409 TT=140.0n
+ XTI=3.0 FC=0.5 EG=1.16 BV=69.5 IBV=1.0e-9)
.MODEL DIO2 D(IS=0.63606f N=1.09748)
.MODEL DIO3 D(IS=1E-20)
.ENDS BA592_IN
*
*
.SUBCKT BAR65-03w_IN 100 200
*Package SOD323:
L1 1 10 0.55nH
C2 10 2 110fF
L2 10 100 0.67nH
L3 2 200 0.55nH
*interne Dioden:
D1 1 2 D1
D2 1 2 D2
R1 1 2 600e9
.MODEL D1 D(IS=4.490e-16 N=1.0856 RS=180.0m XTI=2.5 EG=1.16
+ CJO=451.35f M=0.103494 VJ=0.224 FC=0.5 TT=45.0n)
.MODEL D2 D(IS=57.3327f N=1.5375 RS=100m XTI=3.0 EG=1.05
+ BV=74.0 IBV=0.2e-9 TT=2.4u)
.ENDS BAR65-03w_IN
*
*

 

[sapphire]

Re: model of PIN diode

Seems like it's a discrete component model since there are inductors.

 

[Borber]

Re: model of PIN diode

Yes these are discrete components. If you are interested on www.infineon.com site
you may find another components. L and C elements are parasitics for belonging package.

 

[drasta]

Re: model of PIN diode

Infenion has some models but you can generate model also in APLAC from diodes characteristics from it's datasheet. Microsemi has great variety of PIN diodes. If you run simulations for lower frequencies models are not so good since diodes have bigger forward resistance and some non-linearities.

 

[hitmo]

Re: model of PIN diode

hi
lot of simulation softwares like ADS, designer, eaglware, awr have builtin pin diode models for thier specific parts, u can also refer to the model described on agilent website

 

[filtershaoyong]

Re: model of PIN diode

@DS do provide PIN model, but I found that the resitance of it in forward biased will not change during Transit Simulation. How to specify the model parameters to solve that question?

 

[borich_03]

Re: model of PIN diode

Look at the https://www.skyworksinc.com/ site - "Application Notes: APN1011, APN1002, APN1003", please.
May be it'll useful for you.

 

[junaid786]

Re: model of PIN diode

I also need a model for pin diode.I found this link HPRFhelp version 2.12

When I copy the text into a text file and import a model in ADS,it gives these things( attached in figure) which I don't know how to use or interconnect because there are one or two things in the generated model I don't understand.Can anyone help me please. Its very urgent.