//Main.c
/*------ RC5 decoder program Version 1.0 (by btbass) 'bob the bass' 4MHz clock
;------ RC5 code is 14 bits each of 1.8mS duration with carrier frequency of 36KHz.
;------ A '0' is a mid pulse transition from high to low.
;------ A '1' is a mid pulse transition from low to high.
;------ The first 2 bits are always 1, for timing calibration.
;------ The next bit is the toggle bit, indicating a new keypress.
;------ Then 5 bits of address and 6 bits of command code.
;------ The IR receiver inverts the data stream. (check, but most do!)
;------ This program uses the first 2 bits to calibrate the timing of one pulse length.
;------ It then waits 3/4 pulse length and looks at the input.
;------ If its high, it waits for a low '0'.
;------ If it's low, it waits for a high '1', then resets the timer on the transition.
;------ It returns 0x01 if the code is ok and 0x00 if an error.
;------ The rc5 system address is returned in address, the command in command.
;------ The toggle bit is bit 5 of the address byte.
;------ Using a 4 Meg xtal with timer divided by 128. */
#include <pic.h>
#include <stdio.h>
#include "rc5decode.h"
__CONFIG(INTIO & WDTDIS & PWRTEN & MCLRDIS);
/*--- globals ---*/
unsigned char command;
unsigned char address;
unsigned char temp;
unsigned char timer;
unsigned char rc5valid;
#define PORTBIT(adr, bit) ((unsigned)(&adr)*8+(bit))
static bit IR_PIN @ PORTBIT(GPIO, 2);
/*--- rc5 decode function ---*/
//static void interrupt
unsigned char rc5decode(void)
{
#asm
;------ calibrate timing
bcf 3,5 ;select bank 0
clrf TMR ;start timer
call Wlow ;get the pulse length
call Whigh
btfsc TMR,7 ;test for timer overflow
goto codeError ;bail out
movf TMR,w ;save pulse length
clrf TMR ;start timer
movwf _timer ;take the pulse length,
movwf _temp ;save it
bcf 3,0 ;clear carry
rrf _temp,f ;divide by 2
bcf 3,0 ;clear carry
rrf _temp,f ;divide by 4
movf _temp,w ;and subtract to get
subwf _timer,f ;3/4 pulse length
movlw 0x0c
movwf _temp ;init bit counter
;------ wait for start of data
nextBit movf _timer,w ;wait 3/4 pulse length
subwf TMR,w
btfss 3,2 ;take a look
goto nextBit
;------ start of data stream
btfss IR_IN ;if its high
goto waitlow ;gonna be an 0
;------ wait for high 1
call Whigh ;if its low
bsf 3,0 ;gonna be a 1
goto clock
;------ wait for low 0
waitlow call Wlow
bcf 3,0 ;gonna be an 0
;------ clock data
clock clrf TMR ;restart timer
rlf _command,f ;save the bit
rlf _address,f
decfsz _temp,f ;done all bits?
goto nextBit
;------ get system address, toggle bit and command code
movf _command,w ;copy low byte
movwf _temp ;into temp
rlf _temp,f ;need to shift 2 bits
rlf _address,f ;into address
rlf _temp,f
rlf _address,f ;system address is 5 bits
movlw 0x3f ;mask system address + toggle bit
andwf _address,f
movlw 0x3f ;mask command code
andwf _command,f ;command code is 6 bits
goto rc5ok ;done ok
;------ wait while low
Wlow btfsc TMR,7 ;test for timer overflow
return ;bail out
btfss IR_IN
goto Wlow
return
;------ wait while high
Whigh btfsc TMR,7 ;test for timer overflow
return ;bail out
btfsc IR_IN
goto Whigh
return
rc5ok movlw 0x01
movwf _rc5valid
goto rc5end
codeError clrf _rc5valid
rc5end nop
#endasm
return rc5valid;
}
static void interrupt
isr(void)
{
if(rc5decode())
{
address &= 0x1F;
if(address == REMOTE_ADDRESS)
printf("%d\r\n",command);
//printf("Address:%d\r\nCommand:%d\r\n\n",address,command);
}
INTF = 0;
}
void main(void)
{
OSCCAL = _READ_OSCCAL_DATA(); // restore oscillator calibration
CMCON = 0x07; // turn off comparator
TRISIO = 0x3E;
OPTION = 0x06;
INTE = 1; // enable the external interrupt
GIE = 1; // Global interrupt enable
while(1);
}
/*--- End of File ---*/